Amiga Plus Special 16/AMIGAplus Sonderheft 16 (1998)(ICP)(DE)[!].iso/pd/anwendungen/evenmore/install

Text File | 1998-08-08 | 12KB | 511 lines

; *************************************************************
;
; $VER: Install_EvenMore 0.48
;
; Install script for EvenMore Copyright ©1996-1998 Chris Perver
;
; *************************************************************

(set old_level @user-level)
(set @default-dest "")
(set lng @language)

(complete 0)

;=============================================================================
; Norsk

(if (= lng "norsk")
(

(set #bad-kick
  (cat "Du må ha minst Kickstart 2.04 for å  installere EvenMore")
)
(set #copy-reqtools      "\nKopierer reqtools.library 38.1436 til LIBS:...")
(set #copy-evenmore      "\nKopierer EvenMore exe-fil...")
(set #copy-documentation "\nKopierer EvenMore dokumentasjon...")
(set #copy-nostalgia     "\nKopierer EvenMore nostalgia...")
(set #copy-iconsstan     "\nKopierer Standard knappe-ikoner ...")
(set #copy-iconsmwb      "\nKopierer MagicWB knappe-ikoner...")
(set #copy-iconsprog     "\nKopierer Program-ikoner...")
(set #copy-iconsdock     "\nKopierer Dokk-ikoner...")
(set #copy-rexx          "\nKopierer ARexx-script...")
(set #copy-pic           "\nKopierer EvenMore bilde...")
(set #select-dest        "Vennligst velg Evenmore-skuffen med den tidligere installasjonen.")
(set #select-destnew     "Vennligst velg stien for installasjon av Evenmore. En skuff kalt Evenmore vil bli laget der.")
(set #select-destdocs    "Vennligst velg stien for installasjon av dokumentasjonen til Evenmore. Den har allerede blitt installert sammen med hovedprogrammet.")
(set #select-destrexx    "Vennligst velg stien for installasjon av ARexx-script. Den har allerede blitt installert sammen med hovedprogrammet.")
(set #query-install      "Ønsker du å oppdatere eller installere EvenMore?")
(set #query-copydocs     "Ønsker du å installere dokumentasjonen til Evenmore på noe annet sted?")
(set #query-copyprefs    "Ønsker du å installere standard preferanse-filen?")
(set #query-copyrexx     "Ønsker du å installere ARexx-script på noe annet sted?")
(set #yes                "Ja")
(set #no                 "Nei")

)

;=============================================================================
; English

(

(set #bad-kick
  (cat "You must at least have Kickstart 2.04 to install EvenMore")
)
(set #copy-reqtools      "\nCopying reqtools.library 38.1436 to LIBS:...")
(set #copy-evenmore      "\nCopying EvenMore executable...")
(set #copy-documentation "\nCopying EvenMore documentation...")
(set #copy-nostalgia     "\nCopying EvenMore nostalgia...")
(set #copy-iconsstan     "\nCopying Standard gadget icons...")
(set #copy-iconsmwb      "\nCopying MagicWB gadget icons...")
(set #copy-iconsprog     "\nCopying Program icons...")
(set #copy-iconsdock     "\nCopying Dock icons...")
(set #copy-rexx          "\nCopying ARexx scripts...")
(set #copy-pic           "\nCopying EvenMore snapshot...")
(set #select-dest        "Please select the EvenMore directory.")
(set #select-destnew     "Please select the path where you want to install EvenMore. A drawer named EvenMore will be created there.")
(set #select-destdocs    "Please select the path where you want to install the EvenMore documentation. It has already been installed along with the main program.")
(set #select-destrexx    "Please select the path where you want to install the ARexx scripts. It has already been installed along with the main program.")
(set #query-install      "Do you wish to install or update EvenMore?")
(set #query-copydocs     "Do you wish to install the EvenMore documentation anywhere else?")
(set #query-copyprefs    "Do you wish to install the default preference file?")
(set #query-copyrexx     "Do you wish to install the ARexx scripts anywhere else?")
(set #yes                "Yes")
(set #no                 "No")

)
)

;=============================================================================
; Make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
  (
    (abort #bad-kick)
  )
)

;=============================================================================
; Install or update
(set install
  (askchoice
     (prompt #query-install)
     (help @askchoice-help)
     (choices "Install" "Update")
  )
)


;-----------------------------------------------------------------------------
; Copy Required libraries

(if (= install 0)
  (
    (copylib
      (prompt #copy-reqtools)
      (help @copylib-help)
      (source "Libs/reqtools.library")
      (dest "LIBS:")
      (confirm)
    )
  )
)
(complete 10)

;-----------------------------------------------------------------------------
; Copy EvenMore executable

(if (= install 0)
  (
    (set programdir
      (askdir
        (prompt  #select-destnew)
        (help @askdir-help)
        (default "RAM:")
        (newpath)
      )
    )
  )
  (
    (set programdir
      (askdir
        (prompt  #select-dest)
        (help @askdir-help)
        (default "EvenMore:")
      )
    )
  )
)

(if (= install 0)
  ; Create EvenMore drawer
  (
    (makedir (tackon programdir "EvenMore")
      (help @makedir-help)
    )

    ; Copy EvenMore drawer icon
    (copyfiles
      (prompt #copy-evenmore)
      (help @copyfiles-help)
      (source "/EvenMore.info")
      (dest programdir)
    )

    (set programdir (tackon programdir "EvenMore"))
  )
)
(set @default-dest programdir)

(copyfiles
  (prompt #copy-evenmore)
  (help @copyfiles-help)
  (source "")
  (dest programdir)
  (pattern "EvenMore")
  (infos)
)
(complete 20)

;-----------------------------------------------------------------------------
; Documentation files

(if (not (exists (tackon programdir "Docs")))
  (
    (makedir (tackon programdir "Docs")
      (help @makedir-help)
    )

    (copyfiles
      (prompt #copy-documentation)
      (help @copyfiles-help)
      (source "Docs.info")
      (dest programdir)
    )
  )
)

(copyfiles
  (prompt #copy-documentation)
  (help @copyfiles-help)
  (source "Docs")
  (dest (tackon programdir "Docs"))
  (all)
  (confirm "expert")
  (infos)
)
(complete 30)

; Ask if documentation should be installed elsewhere

(if
  (askbool
    (prompt #query-copydocs)
    (choices #yes #no)
    (default 0)
    (help @askbool-help)
  )
  (
    (set doit 1)
  )
  (
    (set doit 0)
  )
)

(if (= doit 1)
  (
    (set docdir
      (askdir
        (prompt #select-destdocs)
        (help @askdir-help)
        (default (tackon programdir "Docs"))
        (newpath)
      )
    )

    (copyfiles
      (prompt #copy-documentation)
      (help @copyfiles-help)
      (source "Docs/EvenMore.doc")
      (dest docdir)
      (infos)
    )

    (copyfiles
      (prompt #copy-documentation)
      (help @copyfiles-help)
      (source "Docs/EvenMore.guide")
      (dest docdir)
      (infos)
    )
  )
)
(complete 40)

;-----------------------------------------------------------------------------
; Copy icons

; OBSOLETE
(if (exists (tackon programdir "Icons/Standard/loadicon.info"))   (delete (tackon programdir "Icons/Standard/loadicon.info") ))
(if (exists (tackon programdir "Icons/Standard/reloadicon.info")) (delete (tackon programdir "Icons/Standard/reloadicon.info") ))
(if (exists (tackon programdir "Docs/EvenMore.doc")) (delete (tackon programdir "Docs/EvenMore.doc") ))
(if (exists (tackon programdir "Docs/EvenMore.doc.info")) (delete (tackon programdir "Docs/EvenMore.doc.info") ))

(if (exists (tackon programdir "Icons/MagicWB/loadicon.info"))   (delete (tackon programdir "Icons/MagicWB/loadicon.info") ))
(if (exists (tackon programdir "Icons/MagicWB/reloadicon.info")) (delete (tackon programdir "Icons/MagicWB/reloadicon.info") ))
(delete (tackon programdir "Icons/#?.info"))


(set iconsdir
  (tackon
    programdir
    "Icons"
  )
)

(if (not (exists iconsdir))
  (
    (makedir iconsdir
      (help @makedir-help)
    )
    (copyfiles
      (prompt #copy-iconsstan)
      (help @copyfiles-help)
      (source "Icons.info")
      (dest programdir)
    )
  )
)

; Standard gadget icons

(if (not (exists (tackon iconsdir "Standard")))
  (
    (makedir (tackon iconsdir "Standard")
      (help @makedir-help)
    )
  )
)

(copyfiles
  (prompt #copy-iconsstan)
  (help @copyfiles-help)
  (source "Icons/Standard/")
  (dest (tackon iconsdir "Standard/"))
  (pattern "#?.info")
  (confirm "expert")
)
(complete 50)

; MagicWB gadget icons

(if (not (exists (tackon iconsdir "MagicWB")))
  (
    (makedir (tackon iconsdir "MagicWB")
      (help @makedir-help)
    )
  )
)

(copyfiles
  (prompt #copy-iconsmwb)
  (help @copyfiles-help)
  (source "Icons/MagicWB/")
  (dest (tackon iconsdir "MagicWB/"))
  (pattern "#?.info")
  (confirm "expert")
)
(complete 60)

; Program icons

(if (not (exists (tackon iconsdir "Program")))
  (
    (makedir (tackon iconsdir "Program")
      (help @makedir-help)
    )
  )
)

(copyfiles
  (prompt #copy-iconsprog)
  (help @copyfiles-help)
  (source "Icons/Program/")
  (dest (tackon iconsdir "Program/"))
  (pattern "#?.info")
  (confirm "expert")
)
(complete 70)

; Dock icons

(if (not (exists (tackon iconsdir "Dock")))
  (
    (makedir (tackon iconsdir "Dock")
      (help @makedir-help)
    )
  )
)

(copyfiles
  (prompt #copy-iconsdock)
  (help @copyfiles-help)
  (source "Icons/Dock/")
  (all)
  (dest (tackon iconsdir "Dock/"))
  (confirm "expert")
)
(complete 80)

;-----------------------------------------------------------------------------
; Copy EvenMore nostalgia dir

(if (not (exists (tackon programdir "Nostalgia")))
  (
    (makedir (tackon programdir "Nostalgia")
      (help @makedir-help)
    )
    (copyfiles
      (prompt #copy-nostalgia)
      (help @copyfiles-help)
      (source "Nostalgia.info")
      (dest programdir)
    )

    (copyfiles
      (prompt #copy-nostalgia)
      (help @copyfiles-help)
      (source "Nostalgia")
      (dest (tackon programdir "Nostalgia"))
      (all)
      (confirm "expert")
    )
  )
)
(complete 85)

;-----------------------------------------------------------------------------
; Copy EvenMore rexx dir

(if (not (exists (tackon programdir "rexx")))
  (
    (makedir (tackon programdir "rexx")
      (help @makedir-help)
    )

    (copyfiles
      (prompt #copy-rexx)
      (help @copyfiles-help)
      (source "rexx")
      (dest (tackon programdir "rexx"))
      (all)
      (confirm "expert")
    )
  )
)

(if
  (askbool
    (prompt #query-copyrexx)
    (choices #yes #no)
    (default 0)
    (help @askbool-help)
  )
  (
    (set doit 1)
  )
  (
    (set doit 0)
  )
)

(if (= doit 1)
  (
    (set rexxdir
      (askdir
        (prompt #select-destrexx)
        (help @askdir-help)
        (default (tackon programdir "Rexx"))
        (newpath)
      )
    )

    (copyfiles
      (prompt #copy-rexx)
      (help @copyfiles-help)
      (source "rexx")
      (dest rexxdir)
      (all)
      (confirm "expert")
    )
  )
)

;-----------------------------------------------------------------------------
; Copy EvenMore lib dir

(if (not (exists (tackon programdir "libs")))
  (
    (makedir (tackon programdir "libs")
      (help @makedir-help)
    )

    (copyfiles
      (prompt #copy-libs)
      (help @copyfiles-help)
      (source "libs")
      (dest (tackon programdir "libs"))
      (all)
    )
  )
)
(complete 90)

;-----------------------------------------------------------------------------
; Copy EvenMore snapshot

(copyfiles
  (prompt #copy-pic)
  (help @copyfiles-help)
  (source "EvenMore.snapshot")
  (dest programdir)
  (confirm "expert")
)

;-----------------------------------------------------------------------------
; Copy EvenMore config

(if
  (askbool
    (prompt #query-copyprefs)
    (choices #yes #no)
    (default 1)
    (help @askbool-help)
  )
  (
    (copyfiles
      (prompt #copy-libs)
      (help @copyfiles-help)
      (source "EvenMore.config")
      (dest programdir)
    )
  )
)
(complete 95)

;-----------------------------------------------------------------------------
; Copy EvenMore installer

(copyfiles
  (prompt #copy-libs)
  (help @copyfiles-help)
  (source "")
  (dest programdir)
  (pattern "Install")
  (infos)
)
(complete 100)

(exit)